49 lines
1.9 KiB
VHDL
49 lines
1.9 KiB
VHDL
// This file is part of www.nand2tetris.org
|
|
// and the book "The Elements of Computing Systems"
|
|
// by Nisan and Schocken, MIT Press.
|
|
// File name: projects/05/Memory.hdl
|
|
|
|
/**
|
|
* The complete address space of the Hack computer's memory,
|
|
* including RAM and memory-mapped I/O.
|
|
* The chip facilitates read and write operations, as follows:
|
|
* Read: out(t) = Memory[address(t)](t)
|
|
* Write: if load(t-1) then Memory[address(t-1)](t) = in(t-1)
|
|
* In words: the chip always outputs the value stored at the memory
|
|
* location specified by address. If load==1, the in value is loaded
|
|
* into the memory location specified by address. This value becomes
|
|
* available through the out output from the next time step onward.
|
|
* Address space rules:
|
|
* Only the upper 16K+8K+1 words of the Memory chip are used.
|
|
* Access to address>0x6000 is invalid. Access to any address in
|
|
* the range 0x4000-0x5FFF results in accessing the screen memory
|
|
* map. Access to address 0x6000 results in accessing the keyboard
|
|
* memory map. The behavior in these addresses is described in the
|
|
* Screen and Keyboard chip specifications given in the book.
|
|
*/
|
|
|
|
CHIP Memory {
|
|
IN in[16], load, address[15];
|
|
OUT out[16];
|
|
|
|
PARTS:
|
|
// loadscreen = address[14] && (!address[13]) && load
|
|
Not(in=address[13], out=notkbd);
|
|
And(a=address[14], b=notkbd, out=pickscreen);
|
|
And(a=pickscreen,b=load, out=loadscreen);
|
|
|
|
// loadram = !address[14] && load
|
|
Not(in=address[14], out=pickram);
|
|
And(a=pickram,b=load, out=loadram);
|
|
RAM16K(in=in,load=loadram,address=address[0..13], out=ramout);
|
|
|
|
// This is only called if MSB(address) == 1
|
|
Screen(in=in, load=loadscreen, address=address[0..12], out=screenout);
|
|
Keyboard(out=kbdout);
|
|
|
|
// MSB(0|1) = RAM|(screen|keyboard)
|
|
Mux16(a=ramout, b=kbdorscreenout, sel=address[14], out=out);
|
|
// address[13] = screen|keyboard
|
|
Mux16(a=screenout, b=kbdout, sel=address[13], out=kbdorscreenout);
|
|
}
|