// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/03/a/RAM8.hdl

/**
 * Memory of 8 registers, each 16 bit-wide. Out holds the value
 * stored at the memory location specified by address. If load==1, then
 * the in value is loaded into the memory location specified by address
 * (the loaded value will be emitted to out from the next time step onward).
 */

CHIP RAM8 {
    IN in[16], load, address[3];
    OUT out[16];

    PARTS:
    // All our registers can just use
    // the same input signal
    // but pick the load from different places
    Register(in=in, load=load1, out=out1);
    Register(in=in, load=load2, out=out2);
    Register(in=in, load=load3, out=out3);
    Register(in=in, load=load4, out=out4);
    Register(in=in, load=load5, out=out5);
    Register(in=in, load=load6, out=out6);
    Register(in=in, load=load7, out=out7);
    Register(in=in, load=load8, out=out8);

    // We take our load signal, DMux it to 8 signals
    // deciding by the address passed to us
    DMux8Way(in=load, sel=address,
      a=load1,
      b=load2,
      c=load3,
      d=load4,
      e=load5,
      f=load6,
      g=load7,
      h=load8);

    // Take the output of all the registers
    // and return based on the address
    Mux8Way16(
      a=out1,
      b=out2,
      c=out3,
      d=out4,
      e=out5,
      f=out6,
      g=out7,
      h=out8,
      sel=address, out=out);
}